-
Notifications
You must be signed in to change notification settings - Fork 1
/
subgine-pkg.cmake
1281 lines (1074 loc) · 43.6 KB
/
subgine-pkg.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
cmake_minimum_required(VERSION 3.15)
#
# Help Printing
#
function(print_help)
message("usage: subgine-pkg <command> [<args>]")
message("")
message("Avalable commands:")
message(" setup Create a profile configuration with given CMake arguments")
message(" install Fetch and install dependencies")
message(" update Install and update local dependencies")
message(" clean Clean all build and cache directories")
message(" prune Delete all cache, installed packages and fetched sources")
message(" remove Remove the specified package")
message(" help Print this help")
endfunction()
set(command-list "update" "clean" "prune" "help" "setup" "install" "remove")
if(${CMAKE_ARGC} LESS 4)
print_help()
elseif(${CMAKE_ARGC} GREATER_EQUAL 4)
if(${CMAKE_ARGV3} STREQUAL "help")
print_help()
elseif(NOT ${CMAKE_ARGV3} IN_LIST command-list)
message(FATAL_ERROR "subgine-pkg: '${CMAKE_ARGV3}' is not a subgine-pkg command. See 'subgine-pkg help'")
else()
set(subgine-pkg-silent OFF)
macro(message)
if(NOT subgine-pkg-silent)
_message(${ARGV})
endif()
endmacro()
#
# Json Parser
#
# This section's code mostly taken from https://github.com/sbellus/json-cmake
#
# Thank you Stefan Bellus!
#
macro(ParseJson prefix jsonString)
cmake_policy(PUSH)
set(json_string "${jsonString}")
string(LENGTH "${json_string}" json_jsonLen)
set(json_index 0)
set(json_AllVariables ${prefix}._all_var)
set(json_ArrayNestingLevel 0)
set(json_MaxArrayNestingLevel 0)
_sbeParse(${prefix})
unset(json_index)
unset(json_AllVariables)
unset(json_jsonLen)
unset(json_string)
unset(json_value)
unset(json_inValue)
unset(json_name)
unset(json_inName)
unset(json_newPrefix)
unset(json_reservedWord)
unset(json_arrayIndex)
unset(json_char)
unset(json_end)
unset(json_ArrayNestingLevel)
foreach(json_nestingLevel RANGE ${json_MaxArrayNestingLevel})
unset(json_${json_nestingLevel}_arrayIndex)
endforeach()
unset(json_nestingLevel)
unset(json_MaxArrayNestingLevel)
cmake_policy(POP)
endmacro()
macro(sbeClearJson prefix)
foreach(json_var ${${prefix}})
unset(${json_var})
endforeach()
unset(${prefix})
unset(json_var)
endmacro()
macro(sbePrintJson prefix)
foreach(json_var ${${prefix}})
message("${json_var} = ${${json_var}}")
endforeach()
endmacro()
macro(_sbeParse prefix)
set(expected_token "")
while(${json_index} LESS ${json_jsonLen})
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
if("\"" STREQUAL "${json_char}")
_sbeParseNameValue(${prefix})
elseif("{" STREQUAL "${json_char}")
list(APPEND ${json_AllVariables} ${prefix})
list(APPEND ${json_AllVariables} ${prefix}._type)
set(${prefix} "")
set(${prefix}._type "object")
_sbeMoveToNextNonEmptyCharacter()
_sbeParseObject(${prefix})
elseif("[" STREQUAL "${json_char}")
_sbeMoveToNextNonEmptyCharacter()
_sbeParseArray(${prefix})
endif()
if(${json_index} LESS ${json_jsonLen})
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
else()
break()
endif()
if ("}" STREQUAL "${json_char}" OR "]" STREQUAL "${json_char}")
break()
endif()
_sbeMoveToNextNonEmptyCharacter()
endwhile()
endmacro()
macro(_sbeParseNameValue prefix)
set(json_name "")
set(json_inName no)
while(${json_index} LESS ${json_jsonLen})
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
# check if name ends
if("\"" STREQUAL "${json_char}" AND json_inName)
set(json_inName no)
_sbeMoveToNextNonEmptyCharacter()
if(NOT ${json_index} LESS ${json_jsonLen})
break()
endif()
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
set(json_newPrefix ${prefix}.${json_name})
list(APPEND ${prefix} ${json_name})
set(json_name "")
if(":" STREQUAL "${json_char}")
_sbeMoveToNextNonEmptyCharacter()
if(NOT ${json_index} LESS ${json_jsonLen})
break()
endif()
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
if("\"" STREQUAL "${json_char}")
_sbeParseValue(${json_newPrefix})
break()
elseif("{" STREQUAL "${json_char}")
list(APPEND ${json_AllVariables} ${prefix})
list(APPEND ${json_AllVariables} ${prefix}._type)
set(${prefix} "")
set(${prefix}._type "object")
_sbeMoveToNextNonEmptyCharacter()
_sbeParseObject(${json_newPrefix})
break()
elseif("[" STREQUAL "${json_char}")
_sbeMoveToNextNonEmptyCharacter()
_sbeParseArray(${json_newPrefix})
break()
else()
# reserved word starts
_sbeParseReservedWord(${json_newPrefix})
break()
endif()
else()
# name without value
list(APPEND ${json_AllVariables} ${json_newPrefix})
set(${json_newPrefix} "")
break()
endif()
endif()
if(json_inName)
# remove escapes
if("\\" STREQUAL "${json_char}")
math(EXPR json_index "${json_index} + 1")
if(NOT ${json_index} LESS ${json_jsonLen})
break()
endif()
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
endif()
set(json_name "${json_name}${json_char}")
endif()
# check if name starts
if("\"" STREQUAL "${json_char}" AND NOT json_inName)
set(json_inName yes)
endif()
_sbeMoveToNextNonEmptyCharacter()
endwhile()
endmacro()
macro(_sbeParseReservedWord prefix)
set(json_reservedWord "")
set(json_end no)
while(${json_index} LESS ${json_jsonLen} AND NOT json_end)
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
if("," STREQUAL "${json_char}" OR "}" STREQUAL "${json_char}" OR "]" STREQUAL "${json_char}")
set(json_end yes)
else()
set(json_reservedWord "${json_reservedWord}${json_char}")
math(EXPR json_index "${json_index} + 1")
endif()
endwhile()
list(APPEND ${json_AllVariables} ${prefix})
string(STRIP "${json_reservedWord}" json_reservedWord)
set(${prefix} ${json_reservedWord})
endmacro()
macro(_sbeParseValue prefix)
cmake_policy(SET CMP0054 NEW) # turn off implicit expansions in if statement
set(json_value "")
set(json_inValue no)
while(${json_index} LESS ${json_jsonLen})
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
# check if json_value ends, it is ended by "
if("\"" STREQUAL "${json_char}" AND json_inValue)
set(json_inValue no)
set(${prefix} ${json_value})
list(APPEND ${json_AllVariables} ${prefix})
_sbeMoveToNextNonEmptyCharacter()
break()
endif()
if(json_inValue)
# if " is escaped consume
if("\\" STREQUAL "${json_char}")
math(EXPR json_index "${json_index} + 1")
if(NOT ${json_index} LESS ${json_jsonLen})
break()
endif()
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
if(NOT "\"" STREQUAL "${json_char}")
# if it is not " then copy also escape character
set(json_char "\\${json_char}")
endif()
endif()
_sbeAddEscapedCharacter("${json_char}")
endif()
# check if value starts
if("\"" STREQUAL "${json_char}" AND NOT json_inValue)
set(json_inValue yes)
endif()
math(EXPR json_index "${json_index} + 1")
endwhile()
endmacro()
macro(_sbeAddEscapedCharacter char)
string(CONCAT json_value "${json_value}" "${char}")
endmacro()
macro(_sbeParseObject prefix)
_sbeParse(${prefix})
_sbeMoveToNextNonEmptyCharacter()
endmacro()
macro(_sbeParseArray prefix)
math(EXPR json_ArrayNestingLevel "${json_ArrayNestingLevel} + 1")
list(APPEND ${json_AllVariables} ${prefix})
list(APPEND ${json_AllVariables} ${prefix}._type)
set(${prefix} "")
set(${prefix}._type "array")
while(${json_index} LESS ${json_jsonLen})
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
if("\"" STREQUAL "${json_char}")
if(NOT DEFINED json_${json_ArrayNestingLevel}_arrayIndex)
set(json_${json_ArrayNestingLevel}_arrayIndex 0)
endif()
# simple value
list(APPEND ${prefix} ${json_${json_ArrayNestingLevel}_arrayIndex})
_sbeParseValue(${prefix}_${json_${json_ArrayNestingLevel}_arrayIndex})
elseif("{" STREQUAL "${json_char}")
if(NOT DEFINED json_${json_ArrayNestingLevel}_arrayIndex)
set(json_${json_ArrayNestingLevel}_arrayIndex 0)
endif()
list(APPEND ${json_AllVariables} ${prefix}_${json_${json_ArrayNestingLevel}_arrayIndex})
list(APPEND ${json_AllVariables} ${prefix}_${json_${json_ArrayNestingLevel}_arrayIndex}._type)
set(${prefix}_${json_${json_ArrayNestingLevel}_arrayIndex} "")
set(${prefix}_${json_${json_ArrayNestingLevel}_arrayIndex}._type "object")
# object
_sbeMoveToNextNonEmptyCharacter()
list(APPEND ${prefix} ${json_${json_ArrayNestingLevel}_arrayIndex})
_sbeParseObject(${prefix}_${json_${json_ArrayNestingLevel}_arrayIndex})
elseif(NOT "]" STREQUAL "${json_char}")
if(NOT DEFINED json_${json_ArrayNestingLevel}_arrayIndex)
set(json_${json_ArrayNestingLevel}_arrayIndex 0)
endif()
list(APPEND ${prefix} ${json_${json_ArrayNestingLevel}_arrayIndex})
_sbeParseReservedWord(${prefix}_${json_${json_ArrayNestingLevel}_arrayIndex})
endif()
if(NOT ${json_index} LESS ${json_jsonLen})
break()
endif()
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
if("]" STREQUAL "${json_char}")
_sbeMoveToNextNonEmptyCharacter()
break()
elseif("," STREQUAL "${json_char}")
math(EXPR json_${json_ArrayNestingLevel}_arrayIndex "${json_${json_ArrayNestingLevel}_arrayIndex} + 1")
endif()
_sbeMoveToNextNonEmptyCharacter()
endwhile()
if(${json_MaxArrayNestingLevel} LESS ${json_ArrayNestingLevel})
set(json_MaxArrayNestingLevel ${json_ArrayNestingLevel})
endif()
math(EXPR json_ArrayNestingLevel "${json_ArrayNestingLevel} - 1")
endmacro()
macro(_sbeMoveToNextNonEmptyCharacter)
math(EXPR json_index "${json_index} + 1")
if(${json_index} LESS ${json_jsonLen})
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
while(${json_char} MATCHES "[ \t\n\r]" AND ${json_index} LESS ${json_jsonLen})
math(EXPR json_index "${json_index} + 1")
string(SUBSTRING "${json_string}" ${json_index} 1 json_char)
endwhile()
endif()
endmacro()
#
# End of Json Parser
#
# ----------------------
#
# Environement Validation
#
set(subgine-pkg-silent ON)
find_package(Git REQUIRED)
set(subgine-pkg-silent OFF)
set(current-directory "${CMAKE_CURRENT_SOURCE_DIR}")
if(NOT EXISTS "${current-directory}/sbg-manifest.json")
message(FATAL_ERROR "A sbg-manifest.json file must be in the current working directory")
endif()
file(READ "sbg-manifest.json" manifest_content)
ParseJson(manifest "${manifest_content}")
if(NOT "${manifest._type}" STREQUAL "object")
message(FATAL_ERROR "The manifest must contain a root object")
endif()
if(NOT DEFINED manifest.installation-path)
message(FATAL_ERROR "The manifest must contain a string member installation-path")
endif()
set(installation-path "${current-directory}/${manifest.installation-path}")
set(test-path "${installation-path}/.test")
set(library-directory-name "module")
set(sources-directory-name "sources")
set(config-directory-name "config")
set(sources-path "${installation-path}/${sources-directory-name}")
set(library-path "${installation-path}/${library-directory-name}")
set(config-path "${installation-path}/${config-directory-name}")
set(build-directory-name "build")
set(built-options-file-name "subgine-pkg-options.txt")
set(built-revision-file-name "subgine-pkg-revision.txt")
set(current-profile "default")
set(config-suffix "${current-profile}")
include(ProcessorCount)
#
# Dependency Functions
#
macro(select_profile profile)
set(current-profile "${profile}")
set(config-suffix "${current-profile}")
endmacro()
macro(select_profile_from_arg variable)
if(DEFINED ${variable})
select_profile("${${variable}}")
endif()
endmacro()
# This function extract an argument value in the form of -DARGUMENT=VALUE
function(argument_value argument-variable cmake-arguments return-value)
set(test-project-path "${test-path}/.extract-arguments")
file(WRITE "${test-project-path}/CMakeLists.txt" "cmake_minimum_required(VERSION 3.14)\nproject(extract-argument NONE)\nfile(WRITE \"./argument-result.txt\" \"\${${argument-variable}}\")")
execute_process(
COMMAND ${CMAKE_COMMAND}
-DCMAKE_FIND_PACKAGE_NO_PACKAGE_REGISTRY=ON
-DCMAKE_FIND_USE_CMAKE_SYSTEM_PATH=OFF
-DCMAKE_FIND_PACKAGE_PREFER_CONFIG=ON
${cmake-arguments} .
WORKING_DIRECTORY "${test-project-path}"
OUTPUT_QUIET
ERROR_QUIET
RESULT_VARIABLE failbit
)
if (NOT ${failbit} EQUAL 0)
message(FATAL_ERROR "Cannot extract argument ${argument-variable} from command line, CMake subprocess failed with return code ${failbit}")
endif()
file(READ "${test-project-path}/argument-result.txt" argument-result)
set(${return-value} "${argument-result}" PARENT_SCOPE)
endfunction()
# This function simply remove the `v` from the tag to get the version number
function(version_from_tag tag return-value)
string(REGEX MATCH "^v" matches "${tag}")
if("${matches}" STREQUAL "v")
string(SUBSTRING "${tag}" 1 -1 version-string)
set(${return-value} "${version-string}" PARENT_SCOPE)
else()
set(${return-value} "${tag}" PARENT_SCOPE)
endif()
endfunction()
# This function generate the string for the version string we put in the `find_package` command
function(dependency_cmake_version_check dependency return-value)
if (NOT ${dependency}.ignore-version)
if(DEFINED ${dependency}.version)
set(version-string-validate "${${dependency}.version}")
elseif(DEFINED ${dependency}.tag)
version_from_tag(${${dependency}.tag} version-string-validate)
else()
set(version-string-validate "")
endif()
if(NOT "${version-string-validate}" STREQUAL "")
if(${${dependency}.strict})
set(${return-value} "${version-string-validate} EXACT" PARENT_SCOPE)
else()
set(${return-value} "${version-string-validate}" PARENT_SCOPE)
endif()
else()
set(${return-value} "" PARENT_SCOPE)
endif()
else()
set(${return-value} "" PARENT_SCOPE)
endif()
endfunction()
# This function validate the json object of a dependency.
# It must have a name, a repository, and a tag or a branch
function(assert_dependency_json_valid dependency)
if(NOT DEFINED ${dependency}.name)
message(FATAL_ERROR "The dependency '${dependency}' must have a name")
endif()
if(NOT DEFINED ${dependency}.repository)
message(FATAL_ERROR "The dependency '${${dependency}.name}' must have a repository specified")
endif()
if(NOT DEFINED ${dependency}.tag AND NOT DEFINED ${dependency}.branch)
message(FATAL_ERROR "The dependency '${${dependency}.name}' must have a tag or branch specified")
endif()
endfunction()
# This function clear the cache if the arguments have changed
function(clean_test_project_if_needed profile cmake-arguments)
if(EXISTS "${test-path}/${profile}/last-arguments.txt")
file(READ "${test-path}/${profile}/last-arguments.txt" last-cmake-arguments)
if (NOT "${cmake-arguments}" STREQUAL "${last-cmake-arguments}")
file(REMOVE_RECURSE "${test-path}/${profile}")
file(MAKE_DIRECTORY "${test-path}/${profile}")
endif()
endif()
endfunction()
# This function check if a dependency is available with the current configuration and CMake flags
function(check_dependency_exist dependency cmake-flags return-value)
set(profile-test-path "${test-path}/${current-profile}")
if (NOT IS_DIRECTORY "${installation-path}")
file(MAKE_DIRECTORY "${installation-path}")
endif()
if (NOT IS_DIRECTORY "${test-path}")
file(MAKE_DIRECTORY "${test-path}")
endif()
if (NOT IS_DIRECTORY "${profile-test-path}")
file(MAKE_DIRECTORY "${profile-test-path}")
endif()
# We cleanup previous cache so we are not affected by it when we change the arguments passed ot a profile
clean_test_project_if_needed("${current-profile}" "${cmake-flags}")
# The following will try to find a subgine metadata file so we get
# all the required module path and prefix path to find the dependency and its dependencies.
file(WRITE "${profile-test-path}/subgine-package-file.cmake" "
cmake_minimum_required(VERSION 3.14)
list(APPEND CMAKE_PREFIX_PATH \"${library-path}/${current-profile}/\")
find_file(sbg-package-config-file subgine-pkg-${${dependency}.name}-${current-profile}.cmake)
message(\"\${sbg-package-config-file}\")")
execute_process(
COMMAND ${CMAKE_COMMAND} ${cmake-flags} -P "${profile-test-path}/subgine-package-file.cmake"
ERROR_VARIABLE sbg-package-config-file
OUTPUT_QUIET
)
set(check-module-paths "")
set(check-prefix-paths "${library-path}/${current-profile}")
string(STRIP "${sbg-package-config-file}" sbg-package-config-file)
if(NOT "${sbg-package-config-file}" STREQUAL "sbg-package-config-file-NOTFOUND")
include("${sbg-package-config-file}")
list(APPEND check-prefix-paths ${found-pkg-${${dependency}.name}-prefix-path})
if(NOT "${found-pkg-${${dependency}.name}-module-path}" STREQUAL "")
list(APPEND check-module-paths "${found-pkg-${${dependency}.name}-module-path}")
endif()
endif()
if(NOT "${check-module-paths}" STREQUAL "")
set(cmake-module-path-command "list(APPEND CMAKE_MODULE_PATH ${check-module-paths})")
endif()
# Finally, we generate the CMake project file and try to run it
dependency_cmake_version_check(${dependency} cmake-version-check)
if (DEFINED ${dependency}.component)
set(dependency_component "COMPONENTS ${${dependency}.component}")
else()
set(dependency_component "")
endif()
if (DEFINED ${dependency}.target)
set(target-cmake-check "if(TARGET ${${dependency}.target})\nelse()\nmessage(SEND_ERROR \"Package ${${dependency}.name} not found\")\nendif()")
else()
set(target-cmake-check "")
endif()
file(WRITE "${profile-test-path}/CMakeLists.txt" "cmake_minimum_required(VERSION 3.14)\nproject(testfindpackage CXX)\nunset(${${dependency}.name}_DIR CACHE)\n${cmake-module-path-command}\nlist(APPEND CMAKE_PREFIX_PATH ${check-prefix-paths})\nfind_package(${${dependency}.name} ${cmake-version-check} ${dependency_component} REQUIRED)\n${target-cmake-check}")
execute_process(
COMMAND ${CMAKE_COMMAND}
-DCMAKE_PROJECT_INCLUDE=${config-path}/${current-profile}-add-prefix-path.cmake
-DCMAKE_FIND_PACKAGE_NO_PACKAGE_REGISTRY=ON
-DCMAKE_FIND_USE_CMAKE_SYSTEM_PATH=OFF
-DCMAKE_FIND_PACKAGE_PREFER_CONFIG=ON
${cmake-flags}
-S "${profile-test-path}"
-B "${profile-test-path}"
RESULT_VARIABLE result-check-dep
OUTPUT_QUIET
ERROR_QUIET
)
# We ran the test, so we write the arguments for the next run
file(WRITE "${profile-test-path}/last-arguments.txt" "${cmake-flags}")
if (${result-check-dep} EQUAL 0)
set(${return-value} ON PARENT_SCOPE)
else()
set(${return-value} OFF PARENT_SCOPE)
endif()
endfunction()
function(update_dependency dependency cmake-flags)
if(NOT IS_DIRECTORY "${sources-path}")
file(MAKE_DIRECTORY "${sources-path}")
endif()
if(IS_DIRECTORY "${sources-path}/${${dependency}.name}/.git")
message(STATUS "Fetching updates for ${${dependency}.name}...")
execute_process(
COMMAND ${GIT_EXECUTABLE} fetch
WORKING_DIRECTORY "${sources-path}/${${dependency}.name}"
ERROR_QUIET
OUTPUT_QUIET
)
else()
file(REMOVE_RECURSE "${sources-path}/${${dependency}.name}")
set(recurse-argument "")
if (DEFINED ${dependency}.fetch-submodules)
if (${${dependency}.fetch-submodules})
set(recurse-argument "--recurse-submodules")
endif()
endif()
execute_process(
COMMAND ${GIT_EXECUTABLE} clone ${${dependency}.repository} ${${dependency}.name} ${recurse-argument}
WORKING_DIRECTORY ${sources-path}
)
endif()
if (DEFINED ${dependency}.tag)
set(checkout-argument "${${dependency}.tag}")
else()
set(checkout-argument "${${dependency}.branch}")
endif()
execute_process(
COMMAND ${GIT_EXECUTABLE} checkout ${checkout-argument}
WORKING_DIRECTORY "${sources-path}/${${dependency}.name}"
ERROR_QUIET
OUTPUT_QUIET
)
if(EXISTS "${sources-path}/${${dependency}.name}/sbg-manifest.json")
message("Reading ${${dependency}.name} dependencies...")
file(READ "${sources-path}/${${dependency}.name}/sbg-manifest.json" manifest_content_${${dependency}.name})
ParseJson(manifest_${${dependency}.name} "${manifest_content_${${dependency}.name}}")
if(NOT "${manifest_${${dependency}.name}._type}" STREQUAL "object")
message(FATAL_ERROR "The manifest for dependency \"${${dependency}.name}\" must contain a root object")
endif()
if (NOT DEFINED manifest_${${dependency}.name}.dependencies)
message(FATAL_ERROR "The manifest for dependency \"${${dependency}.name}\" does not contains dependencies or is invalid")
endif()
update_dependency_list(manifest_${${dependency}.name}.dependencies "${cmake-flags}")
endif()
should_rebuild_dependency(${dependency} ASSUME_LOCAL "${cmake-flags}" should-rebuild)
if(should-rebuild)
build_dependency(${dependency} "${cmake-flags}")
endif()
endfunction()
function(write_dependency_options_file dependency cmake-flags)
file(WRITE "${sources-path}/${${dependency}.name}/${build-directory-name}/${config-suffix}/${built-options-file-name}" "${${dependency}.options};${cmake-flags}")
endfunction()
function(write_dependency_revision_file dependency)
dependency_current_revision(${dependency} current-revision)
file(WRITE "${sources-path}/${${dependency}.name}/${build-directory-name}/${config-suffix}/${built-revision-file-name}" "${current-revision}")
endfunction()
function(dependency_cmake_options dependency return-value)
set(cmake-options ${${dependency}.options})
separate_arguments(cmake-options)
set(${return-value} ${cmake-options} PARENT_SCOPE)
endfunction()
function(dependency_build_additional_flags dependency return-value)
ProcessorCount(cores)
if(${cores} GREATER 0)
set(additional-arguments "--parallel ${cores}")
separate_arguments(additional-arguments)
set(${return-value} ${additional-arguments} PARENT_SCOPE)
else()
set(${return-value} "" PARENT_SCOPE)
endif()
endfunction()
function(build_dependency dependency cmake-flags)
set(build-directory "${sources-path}/${${dependency}.name}/${build-directory-name}/${config-suffix}")
set(sources-directory "${sources-path}/${${dependency}.name}")
if(NOT IS_DIRECTORY "${build-directory}")
file(MAKE_DIRECTORY "${build-directory}")
endif()
dependency_cmake_options(${dependency} cmake-options)
execute_process(
COMMAND ${CMAKE_COMMAND} ${cmake-flags} -Dsubgine-pkg-as-dependency=ON
-DCMAKE_INSTALL_PREFIX=${library-path}/${config-suffix}/${${dependency}.name}
-DCMAKE_PROJECT_INCLUDE=${config-path}/${current-profile}-add-prefix-path.cmake
-DCMAKE_EXPORT_NO_PACKAGE_REGISTRY=ON
-DCMAKE_FIND_USE_CMAKE_SYSTEM_PATH=OFF
-DCMAKE_FIND_PACKAGE_PREFER_CONFIG=ON
${cmake-options}
-S "${sources-directory}"
-B "${build-directory}"
RESULT_VARIABLE result-build-dependency
ERROR_VARIABLE build-dependency-error
OUTPUT_QUIET
)
message(STATUS "Configuring ${${dependency}.name}...")
if (NOT ${result-build-dependency} EQUAL 0)
message("Dependency ${${dependency}.name} failed to configure... aborting")
message("Failed to configure with output:\n${build-dependency-error}")
message(FATAL_ERROR "stopping due to previous errors")
endif()
dependency_build_additional_flags(${dependency} additional-flags)
message(STATUS "Building ${${dependency}.name}...")
execute_process(
COMMAND ${CMAKE_COMMAND} --build . --target install ${additional-flags}
WORKING_DIRECTORY "${sources-path}/${${dependency}.name}/${build-directory-name}/${config-suffix}"
RESULT_VARIABLE result-build-dependency
ERROR_VARIABLE build-dependency-error
OUTPUT_QUIET
)
if (${result-build-dependency} EQUAL 0)
write_dependency_revision_file(${dependency})
write_dependency_options_file(${dependency} "${cmake-flags}")
else()
message("Dependency ${${dependency}.name} failed to build... aborting")
message("Failed to build with output:\n${build-dependency-error}")
message(FATAL_ERROR "stopping due to previous errors")
endif()
message("Installed ${${dependency}.name} ✔")
check_dependency_exist(${dependency} "${cmake-flags}" dependency-${${dependency}.name}-exists)
endfunction()
function(dependency_has_local_source_dir dependency return-value)
if(IS_DIRECTORY "${sources-path}/${${dependency}.name}")
set(${return-value} ON PARENT_SCOPE)
else()
set(${return-value} OFF PARENT_SCOPE)
endif()
endfunction()
function(update_dependency_list dependency-list cmake-flags)
foreach(dependency-id ${${dependency-list}})
set(dependency ${dependency-list}_${dependency-id})
if(NOT ${${dependency}._type} STREQUAL "object")
message(FATAL_ERROR "The dependency array must only contain objects")
endif()
assert_dependency_json_valid(${dependency})
check_dependency_exist(${dependency} "${cmake-flags}" dependency-${${dependency}.name}-exists)
endforeach()
foreach(dependency-id ${${dependency-list}})
set(dependency ${dependency-list}_${dependency-id})
dependency_has_local_source_dir(${dependency} is-local)
if (NOT ${dependency-${${dependency}.name}-exists})
message("${${dependency}.name} not found... installing")
update_dependency(${dependency} "${cmake-flags}")
elseif(is-local)
dependency_current_revision(${dependency} current-revision)
dependency_built_revision(${dependency} built-revision)
dependency_built_options(${dependency} built-options)
if(NOT "${built-options}" STREQUAL "${${dependency}.options};${cmake-flags}")
message("${${dependency}.name} options changed... rebuilding")
update_dependency(${dependency} "${cmake-flags}")
elseif(NOT "${current-revision}" STREQUAL "${built-revision}")
message("${${dependency}.name} build out of date... rebuilding")
update_dependency(${dependency} "${cmake-flags}")
else()
message("Found ${${dependency}.name} ✔")
endif()
else()
message("Found ${${dependency}.name} ✔")
endif()
endforeach()
endfunction()
function(update_local_dependency_list dependency-list cmake-flags)
foreach(dependency-id ${${dependency-list}})
set(dependency ${dependency-list}_${dependency-id})
if(NOT ${${dependency}._type} STREQUAL "object")
message(FATAL_ERROR "The dependency array must only contain objects")
endif()
assert_dependency_json_valid(${dependency})
check_dependency_exist(${dependency} "${cmake-flags}" dependency-${${dependency}.name}-exists)
endforeach()
file(READ "${test-path}/${current-profile}/CMakeCache.txt" test-cache)
foreach(dependency-id ${${dependency-list}})
set(dependency ${dependency-list}_${dependency-id})
if (${dependency-${${dependency}.name}-exists})
update_local_dependency(${dependency} ${test-cache} "${cmake-flags}")
endif()
endforeach()
update_dependency_list(${dependency-list} "${cmake-flags}")
endfunction()
function(dependency_current_revision dependency return-value)
execute_process(
COMMAND ${GIT_EXECUTABLE} rev-parse HEAD
WORKING_DIRECTORY "${sources-path}/${${dependency}.name}"
OUTPUT_VARIABLE revision-current
RESULT_VARIABLE revision-current-result
ERROR_VARIABLE revision-current-error
)
if ("${revision-current-result}" EQUAL 0)
set(${return-value} "${revision-current}" PARENT_SCOPE)
else()
message(FATAL_ERROR "Git failed to retrieve current revision with output: ${revision-current-error}")
endif()
endfunction()
function(dependency_built_options dependency return-value)
if(EXISTS "${sources-path}/${${dependency}.name}/${build-directory-name}/${config-suffix}/${built-options-file-name}")
file(READ "${sources-path}/${${dependency}.name}/${build-directory-name}/${config-suffix}/${built-options-file-name}" built-options-string)
set(${return-value} "${built-options-string}" PARENT_SCOPE)
else()
set(${return-value} "" PARENT_SCOPE)
endif()
endfunction()
function(dependency_built_revision dependency return-value)
if(EXISTS "${sources-path}/${${dependency}.name}/${build-directory-name}/${config-suffix}/${built-revision-file-name}")
file(READ "${sources-path}/${${dependency}.name}/${build-directory-name}/${config-suffix}/${built-revision-file-name}" built-revision-string)
set(${return-value} "${built-revision-string}" PARENT_SCOPE)
else()
set(${return-value} "" PARENT_SCOPE)
endif()
endfunction()
function(should_rebuild_dependency dependency test-build-cache cmake-flags return-value)
if ("${test-build-cache}" STREQUAL "ASSUME_LOCAL")
set(is-local-dependency ON)
else()
check_local_dependency(${dependency} ${test-build-cache} is-local-dependency)
endif()
if(is-local-dependency)
dependency_current_revision(${dependency} current-revision)
dependency_built_revision(${dependency} built-revision)
dependency_built_options(${dependency} built-options)
if("${current-revision}" STREQUAL "${built-revision}" AND "${built-options}" STREQUAL "${${dependency}.options};${cmake-flags}" AND EXISTS ${library-path}/${current-profile}/${${dependency}.name})
set(${return-value} OFF PARENT_SCOPE)
else()
set(${return-value} ON PARENT_SCOPE)
endif()
else()
set(${return-value} OFF PARENT_SCOPE)
endif()
endfunction()
function(check_local_options test-build-cache return-value)
check_local_dependency(${dependency} ${test-build-cache} is-local-package)
set(check-local-options OFF)
if(is-local-package)
dependency_built_options(${dependency} built-options)
if("${built-options}" STREQUAL "${${dependency}.options}")
set(check-local-options OFF)
else()
set(check-local-options ON)
endif()
endif()
if (${check-local-options})
set(${return-value} ON PARENT_SCOPE)
else()
set(${return-value} OFF PARENT_SCOPE)
endif()
endfunction()
function(check_local_dependency dependency test-build-cache return-value)
set(check-local-package OFF)
dependency_has_local_source_dir(${dependency} is-local)
if(is-local)
string(REGEX MATCH "${${dependency}.name}_DIR:PATH=[^\n]*" matched-path "${test-build-cache}")
if ("${matched-path}" STREQUAL "")
if(ARGC GREATER 3 AND "${ARGV3}" STREQUAL "SKIPPING_VERBOSE")
message("${${dependency}.name} is not a cmake package... skipping")
endif()
else()
string(LENGTH "${${dependency}.name}_DIR:PATH=" path-prefix-length)
string(SUBSTRING "${matched-path}" ${path-prefix-length} -1 dependency-path)
if ("${dependency-path}" MATCHES "${installation-path}/[^\n]*")
set(check-local-package ON)
endif()
endif()
endif()
if (${check-local-package})
set(${return-value} ON PARENT_SCOPE)
else()
set(${return-value} OFF PARENT_SCOPE)
endif()
endfunction()
function(check_branch_status dependency return-value)
set(check-branch-status OFF)
if(DEFINED ${dependency}.branch)
execute_process(
COMMAND ${GIT_EXECUTABLE} symbolic-ref -q --short HEAD
OUTPUT_VARIABLE branch-result
WORKING_DIRECTORY "${sources-path}/${${dependency}.name}"
ERROR_QUIET
)
string(REGEX REPLACE "\n$" "" branch-result "${branch-result}")
if(NOT "${branch-result}" STREQUAL "${${dependency}.branch}")
set(check-branch-status ON)
endif()
else()
execute_process(
COMMAND ${GIT_EXECUTABLE} describe --tags --exact-match
OUTPUT_VARIABLE branch-result
WORKING_DIRECTORY "${sources-path}/${${dependency}.name}"
ERROR_QUIET
)
string(REGEX REPLACE "\n$" "" branch-result "${branch-result}")
if(NOT "${branch-result}" STREQUAL "${${dependency}.tag}")
set(check-branch-status ON)
endif()
endif()
if (${check-branch-status})
set(${return-value} ON PARENT_SCOPE)
else()
set(${return-value} OFF PARENT_SCOPE)
endif()
endfunction()
function(update_local_dependency dependency test-build-cache cmake-flags)
dependency_has_local_source_dir(${dependency} is-local-package)
if(is-local-package)
check_branch_status(${dependency} should-checkout)
if(${should-checkout})
if (DEFINED ${dependency}.tag)
set(checkout-argument "${${dependency}.tag}")
message("${${dependency}.name}: checkout tag ${${dependency}.tag}")
else()
set(checkout-argument "${${dependency}.branch}")
message("${${dependency}.name}: checkout branch ${${dependency}.branch}")
endif()
execute_process(
COMMAND ${GIT_EXECUTABLE} fetch
WORKING_DIRECTORY "${sources-path}/${${dependency}.name}"
OUTPUT_QUIET
)
execute_process(
COMMAND ${GIT_EXECUTABLE} checkout ${checkout-argument}
WORKING_DIRECTORY "${sources-path}/${${dependency}.name}"
OUTPUT_QUIET
)
message("${${dependency}.name} HEAD changed... rebuilding")
endif()
if (DEFINED ${dependency}.branch)
message("Pulling ${${dependency}.name}...")
set(recurse-argument "")
if (DEFINED ${dependency}.fetch-submodules)
if (${${dependency}.fetch-submodules})
set(recurse-argument "--recurse-submodules")
endif()
endif()
execute_process(
COMMAND ${GIT_EXECUTABLE} pull ${recurse-argument}
OUTPUT_VARIABLE pull-result
WORKING_DIRECTORY "${sources-path}/${${dependency}.name}"
ERROR_QUIET
)
dependency_current_revision(${dependency} pulled-revision)
dependency_built_revision(${dependency} built-revision)
if(NOT "${pulled-revision}" STREQUAL "${built-revision}")
message("${${dependency}.name} branch updated... rebuilding")